/**
 * A TV simulator, drawing in only red, green and blue.
 * Inspired by a sequence in the film 'Zidane: a 21st Century Portrait'.
 * My first Processing sketch!
 * <li> First, CLICK in the image to get 'focus'.
 * <li> Move the mouse over the picture left/right to change the brightness.
 * <li> Click in the picture for focus, then use the R, G and B keys to toggle cells.
 * <li> Press 1, 2, 3, 4 to change the channel.
 * <li> Aaron Bell Oct06, finally published Feb08 :-O
 */

PImage a;

float BRIGHTNESS;
int MAX_BRIGHTNESS=2;  // used to scale the brightness by mouse position
int BRIGHTNESS_COEFF;  // how much to scale the brightness

float perlin_delta=0.3;  // higher = more random interference
float perlin_pos=0.0;

int CELL_WIDTH=5;
int CELL_HEIGHT=4;

boolean redOn = true;
boolean greenOn = true;
boolean blueOn = true;
boolean mouseEverMoved = false;

void setup()
{
  a = loadImage("rgbtest150.jpg");
  // fix the size for a correct Processing export:
  size(750,452);
  // ...because this will be very large for most images:
  size(a.width * CELL_WIDTH, a.height * CELL_HEIGHT);
  BRIGHTNESS_COEFF=(a.width * CELL_WIDTH)/MAX_BRIGHTNESS;
  background(0);
  frameRate(8);
  
  BRIGHTNESS = 1.5;
  drawRgb(CELL_WIDTH, CELL_HEIGHT);
}

void changeChannel(String file)
{
  a = loadImage(file);
}

void drawRgb(int cellWidth, int cellHeight)
{
  for (int y=0; y<a.height; y++)
  {
    for (int x=0; x<a.width; x++)
    {
      // move in perlin landscape
      perlin_pos += perlin_delta;
      // normalize to 0.5-1.5 range
      float cell_perturb = noise(perlin_pos) + 0.5;
      // adjust this cell's brightness
      float cell_brightness = BRIGHTNESS * cell_perturb;
      
      // get the image data in RGB
      int loc = x + y*a.width;
      float r = red(a.pixels[loc]);
      float g = green(a.pixels[loc]);
      float b = blue(a.pixels[loc]);

      // top left of our larger RGB cell
      int xp = x*cellWidth;
      int yp = y*cellHeight;
      if (redOn)
      {
        stroke(r*cell_brightness,0,0);
        line(xp,yp,xp,yp+2);
      }
      if (greenOn)
      {
        stroke(0,g*cell_brightness,0);
        line(xp+1,yp,xp+1,yp+2);
      }
      if (blueOn)
      {
        stroke(0,0,b*cell_brightness);
        line(xp+2,yp,xp+2,yp+2);
      }
    }
  }
}

void mouseMoved()
{
  mouseEverMoved = true;
}

void draw()
{
    if (mouseEverMoved) BRIGHTNESS = (float)mouseX/BRIGHTNESS_COEFF;
    drawRgb(CELL_WIDTH, CELL_HEIGHT);
}

void keyReleased()
{
  if (key == 'r') redOn = !redOn;
  else if (key == 'g') greenOn = !greenOn;
  else if (key == 'b') blueOn = !blueOn;
  else if (key == '1') changeChannel("rgbtest150.jpg");
  else if (key == '2') changeChannel("rgbgamut150.jpg");
  else if (key == '3') changeChannel("mondrian150.jpg");
  else if (key == '4') changeChannel("field150.jpg");
  background(0);
  drawRgb(CELL_WIDTH, CELL_HEIGHT);
}